Скрипт для преобразования динамического списка адресов в статический

Еще один способ для всех списков: # Преобразовать динамические записи в статические в address-lists, чтобы динамические записи не удалялись после перезагрузки роутера.  
:local comment  
:local address  
:local list  
:local disabled  
:local found  

:set found 0;

/ip firewall address-list  
:foreach a in=[find] do={
  :if ([get $a dynamic] = true) do={
     /system logging disable 0  
     :set found 1;  
     :set comment [get $a comment]
     :set address [get $a address]
     :set list [get $a list]
     :set disabled [get $a disabled]
     remove $a  
     add address=$address list=$list comment=$comment disabled=$disabled  
  }  
}  
:if ($found=1) do={  
/system logging enable 0  
:log info "Преобразование из динамического в статическое завершено. Журналирование системы включено."  
:set found 0;  
}

Комментирование и отключение не поддерживаются для динамических записей, используйте более простой способ: понимаю, зачем отключают лог, но хардкодить это прямо внутрь — ошибка, может мешать другим скриптам или функциям…

:local list  
:local address  

:log info "Начато преобразование динамических записей в статические"

/ip firewall address-list  
:foreach a in=[find where dynamic=true] do={
     :set list [get $a list]
     :set address [get $a address]
     remove $a  
     add list=$list address=$address disabled=no  
}

:log info "Преобразование динамических записей в статические завершено"