скрипт включения / выключения радио

Была задача настроить беспроводной радиомодуль на RB751U так, чтобы он включался и выключался в определённое время. Например, включался только в рабочие часы (07:00 - 17:00). Самое простое решение — использовать планировщик для включения и отключения радио в нужное время. Однако, если роутер будет выключен ночью, а включиться уже после времени включения 07:00, событие включения по расписанию просто не сработает, и радио останется выключенным. Этот скрипт проверяет с нужным пользователю интервалом, должен ли радио быть включён или выключен, и устанавливает состояние соответственно. Его можно адаптировать, например, для включения и отключения 3G-модема WAN, если нужно, чтобы роутер имел активное интернет-соединение только в определённые часы.

# Скрипт для управления включением и выключением беспроводного радиомодуля #
# в выбранные пользователем интервалы времени #
# Включение и выключение радио не будет выполнено, если системное время #
# не синхронизировано с локальным, если только это не требуется #
# Помните, что после перезагрузки роутер сбрасывает время на заводское #
# Запускайте этот скрипт по расписанию с нужным интервалом #
# Автор Peter James, 2012-07-19 #
# Тестировался на RB751U и RouterOS v5.19 #

#####################################
## Установите время включения и выключения радио здесь ##
:local RadioOnTime "07:00";
:local RadioOffTime "17:00";

# Установите "no", если часы устанавливаются вручную после каждой перезагрузки #
# Установите "yes", если время синхронизируется через NTP-клиент #
:local UseNTPClientStatus "yes";
#####################################

:log info "Запуск скрипта RadioOnOff";
# Получаем имя интерфейса wlan радио #
:local RadioName [/interface get [find type=wlan] name];
:log info "Имя радио = $RadioName";

# Проверяем, синхронизированы ли часы системы с локальным временем #
:local NTPSyncState [/system ntp client get status];
:log info "Статус NTP-клиента = $NTPSyncState";

# Не выполняем включение или выключение радио, если текущее реальное время неизвестно, если это не требуется #
:if (($NTPSyncState="synchronized") or ($UseNTPClientStatus="no")) do {

:local CurrentTime [/system clock get time];
:log info "Текущее время = $CurrentTime";

# Проверяем текущий статус включения радио #
:local RadioDisabled [/interface get $RadioName disabled];
:log info "Радио отключено = $RadioDisabled";

# Если время включения раньше времени выключения #
:if ($RadioOnTime < $RadioOffTime) do {

# Радио должно быть включено между этими временами #
:if (($CurrentTime > $RadioOnTime) and ($CurrentTime < $RadioOffTime)) do {

if ($RadioDisabled=true) do {
:log info "Радио было OFF, теперь включаем";
/interface enable $RadioName;
}
} else {

if ($RadioDisabled=false) do {
:log info "Радио было ON, теперь выключаем";
/interface disable $RadioName;
}

}

}

# Если время включения позже времени выключения #
:if ($RadioOnTime > $RadioOffTime) do {

# Радио должно быть выключено между этими временами #
:if (($CurrentTime < $RadioOnTime) and ($CurrentTime > $RadioOffTime)) do {

if ($RadioDisabled=false) do {
:log info "Радио было ON, теперь выключаем";
/interface disable $RadioName;
}
} else {

if ($RadioDisabled=true) do {
:log info "Радио было OFF, теперь включаем";
/interface enable $RadioName;
}

}

}

} else {

:log info "Часы системы могут не быть синхронизированы с локальным временем, операция невозможна";

}

:log info "Скрипт RadioOnOff завершён";

Я попробовал это, но не работает. В логах появляется “Radio name = wlan1”, и больше ничего. Нужно ли ставить какие-то пакеты, чтобы это заработало? Моя версия 5.14, а оборудование — RB411U.

К сожалению, такой свойства, как «status», нет:

[user@router] > /system ntp client get
active-server    enabled          last-bad-packet-before  last-bad-packet-reason  last-update-from  poll-interval  secondary-ntp    
value-name dynamic-servers  last-adjustment  last-bad-packet-from    last-update-before      mode              primary-ntp    
server-dns-names

[user@router] > /system ntp client print
enabled: yes
primary-ntp: 194.109.22.18
secondary-ntp: 216.171.120.36
mode: unicast
poll-interval: 15m
active-server: 194.109.22.18
last-update-from: 194.109.22.18
last-update-before: 4m13s310ms
last-adjustment: 4ms590us
last-bad-packet-from: 216.171.120.36
last-bad-packet-before: 17h6m33s300ms
last-bad-packet-reason: server-not-synchronized

Смотри мануал: http://wiki.mikrotik.com/wiki/Manual:System/Time

Возможно, стоит проверить, больше ли значение last-bad-packet-before, чем last-update-before. Если да, значит успешное обновление было недавно, а ошибка — раньше, и можно считать, что с временем всё в порядке. Также я бы проверил, чтобы last-update-before не был старше разумного периода (например, 24 часов).

Я протестировал все решения из этого поста на версии 5.25 для отключения/включения WLAN, но при этом проводное соединение тоже падает. Есть идеи? Спасибо.

Я тоже установил пакет NTP, но результат все тот же.

Кто-нибудь???