/ tool fetch — как получить данные от телеграм-бота?

Вы можете отправить, например, созданную собственную команду через Telegram-бота на ваш роутер. (В пакете BlackVS есть два примера команд, которые помогают понять, как это сделать.) Например, я хочу узнать, какие устройства сейчас в сети — тогда я отправляю ключевую команду /onlineDevices через Telegram, роутер Mikrotik регулярно проверяет Telegram-бота (через планировщик), получает команду, интерпретирует её и отправляет соответствующий ответ (текущие онлайн-устройства) обратно боту и, соответственно, на мой смартфон.

### получение DHCP аренды START

:local send [:parse [/system script get tg_sendMessage source]]

:local i;  
:local hostip;  
:local hostname;  
:local macaddress;  
:local dhcplist "";  
#:local cmt "";  
:local leaseStatus "";  
:local PINGCOUNT "3";  
:local CURRENTSTATUS "";  
:local leasesall [ :len [ /ip dhcp-server lease find where server=dhcp1 ] ];

/ip dhcp-server lease;  
:foreach i in=[find where server=dhcp1 ] do={
   :set $hostname [get $i host-name];
   :if ( [:len $hostname] = 0) do={
       :set $hostname [get $i comment];
       :if ( [:len $hostname] = 0) do={
           :set $hostname "NoHostName-NoComment";  
       }    
   }  
   :set $leaseStatus [get $i status];
   :set $hostip [get $i address];
   :if ([/ping $hostip interval=1s count=$PINGCOUNT] > ($PINGCOUNT / 2)) do={
       ## если устройство отвечает как минимум на половину пингов, значит, онлайн  
       :set $CURRENTSTATUS "online";  
   } else= {  
       :set $CURRENTSTATUS "offline";    
   }  
     
   :set $dhcplist ("*" . $hostname . "*" . " - статус: _" . $CURRENTSTATUS . "_%0A" . $dhcplist);  
};  
### получение DHCP аренды END

:put $params;  
:put $chatid;  
:put $from;  

#:log info $dhcplist;  
 
:local text "Router Id:* $[/system identity get name] * %0A\
_DHCP leases_ %0A\
$dhcplist";

:put ("Текст: $text");  
:log info $text;  
 
$send chat=$chatid text=$text mode="Markdown";  
:return true;