GRE Tunnel на динамическом IP-адресе.

Я понимаю, что когда я отвечаю, эта тема уже старая, но мне показалось подходящим местом, чтобы выложить простое скриптовое решение для обновления удаленного адреса GRE-туннеля, когда этот удаленный адрес динамический. Это предполагает, что GRE-туннель уже работает, а удаленный IP-адрес WAN зарегистрирован/доступен через какой-то сервис динамического DNS, например, DynDns и т.д. Скрипт — это однострочное утверждение, которое просто обновляет удаленный адрес; он не предусматривает проверки необходимости обновления, ведения логов или проверки ошибок. При необходимости их можно добавить. /interface gre set “gre-tunnel1” remote-address=[:resolve “ yournamehere.dyndns.org ”] Надеюсь, это может быть полезно кому-нибудь.

У Cisco есть GRE multipoint tunnels для решения именно этой ситуации (статический сервер, динамический IP-адрес клиента), Mikrotik такой возможности не предлагает. Вам придется использовать L2TP, а затем либо протянуть GRE/EoIP туннель поверх L2TP сессии, либо использовать L2TP без дополнительного туннеля сверху.

Вот перевод текста сообщения на русский язык:

Ниже приведен немного более сложный скрипт, который ищет все GRE-туннели с комментарием, начинающимся со строки "Host_". Вторая часть строки комментария должна быть fqdn динамического хоста. Благодаря этому он выполнит DNS-разрешение динамического имени хоста и обновит удаленный адрес интерфейса GRE, только если он отличается от текущей настройки.

# определить переменные
:local list
:local thecomment
:local thecommentlen
:local thename
:local newip
:local oldip

:foreach i in=[ /interface gre find where comment~"^Host_" ] do={
  :set thecomment [/interface gre get $i comment]
  :set thecommentlen [ :len $thecomment ]
  :set thename [ :pick $thecomment 5 $thecommentlen ]
  :set oldip [/interface gre get $i remote-address]
  :set newip [:resolve $thename]
  : if ($newip != $oldip) do={ /interface gre set $i remote-address=$newip}
  : if ($newip != $oldip) do={:log info ("Updating " . $thecomment . " from " . $oldip . " to " . $newip . ".")}    
}

Итак, что если у вас также включен IPSec на туннеле и он не использует политику по умолчанию? (то есть, вы не можете просто ввести PSK в определении интерфейса GRE). В этом случае вам нужно будет расширить скрипт для обновления вашего IPSec Peer и Policy. Просто следуйте тому же правилу комментария как для IPSec policy, так и для IPSec peer. Это позволит нижеприведенному скрипту находить правильные записи и обновлять их все.

# определить переменные
:local list
:local thecomment
:local thecommentlen
:local thename
:local newip
:local newipm
:local oldip

:foreach i in=[ /interface gre find where comment~"^Host_" ] do={
  :set thecomment [ /interface gre get $i comment ]
  :set thecommentlen [ :len $thecomment ]
  :set thename [ :pick $thecomment 5 $thecommentlen ]
  :set oldip [ /interface gre get $i remote-address ]
  :set newip [ :resolve $thename ]
  :set newipm ( $newip . "/32" )
  : if ($newip != $oldip) do={ /interface gre set $i remote-address=$newip}
  : if ($newip != $oldip) do={:log info ("gre Interface - Updating " . $thecomment . " from " . $oldip . " to " . $newip . ".")}    
}

:foreach i in=[ /ip ipsec policy find where comment~"^Host_" ] do={
  :set thecomment [ /ip ipsec policy get $i comment ]
  :set thecommentlen [ :len $thecomment ]
  :set thename [ :pick $thecomment 5 $thecommentlen ]
  :set oldip [ /ip ipsec policy get $i sa-dst-address]
  :set newip [:resolve $thename ]
  :set newipm ( $newip . "/32" )
  : if ($newip != $oldip) do={ /ip ipsec policy set $i dst-address=$newipm sa-dst-address=$newip }
  : if ($newip != $oldip) do={ :log info ("IPSec Policy - Updating " . $thecomment . " from " . $oldip . " to " . $newip . ".") }    
}

:foreach i in=[ /ip ipsec peer find where comment~"^Host_" ] do={
  :set thecomment [ /ip ipsec peer get $i comment ]
  :set thecommentlen [ :len $thecomment ]
  :set thename [ :pick $thecomment 5 $thecommentlen ]
  :set oldip [ /ip ipsec peer get $i address]
  :set newip [:resolve $thename]
  :set newip ( $newip . "/32" )
  : if ($newip != $oldip) do={ /ip ipsec peer set $i address=$newip }
  : if ($newip != $oldip) do={ :log info ("IPSec Peer - Updating " . $thecomment . " from " . $oldip . " to " . $newip . ".")}    
}