Скрипт обновления Dyndns для PPPOE

# Задаём нужные переменные  
:local username "YOURUSER"  
:local password "YOURPASWORD"  
:local hostname "YOURHOSTNAME.dyndns.org"  

:global dyndnsForce  
:global previousIP  

# выводим отладочную информацию  
:log info ("UpdateDynDNS: username = $username")  
:log info ("UpdateDynDNS: password = $password")  
:log info ("UpdateDynDNS: hostname = $hostname")  
:log info ("UpdateDynDNS: previousIP = $previousIP")  

# получаем текущий IP-адрес из интернета (на случай двойного NAT)  
/tool fetch mode=http address="checkip.dyndns.org" src-path="/" dst-path="/dyndns.checkip.html"  
:delay 1  
:local result [/file get dyndns.checkip.html contents]

# парсим полученный IP  
:local resultLen [:len $result]
:local startLoc [:find $result ": " -1]
:set startLoc ($startLoc + 2)  
:local endLoc [:find $result "</body>" -1]
:local currentIP [:pick $result $startLoc $endLoc]
:log info "UpdateDynDNS: currentIP = $currentIP"  

# Уберите # со следующей строки, чтобы заставить обновлять адрес каждый раз — удобно для отладки,  
# но есть риск попасть в чёрный список DynDNS!  

#:set dyndnsForce true  

# Определяем, нужно ли обновлять dyndns  
# подробности по запросу к dyndns updater: http://www.dyndns.com/developers/specs/syntax.html  

:if (($currentIP != $previousIP) || ($dyndnsForce = true)) do={  
  :set dyndnsForce false  
  :set previousIP $currentIP  
  :log info "$currentIP or $previousIP"  
  /tool fetch user=$username password=$password mode=http address="members.dyndns.org" \  
     src-path="nic/update?system=dyndns&hostname=$hostname&myip=$currentIP&wildcard=no­" \  
     dst-path="/dyndns.txt"  
  :delay 1  
  :local result [/file get dyndns.txt contents]
  :log info ("UpdateDynDNS: Dyndns update needed")  
  :log info ("UpdateDynDNS: Dyndns Update Result: ".$result)  
  :put ("Dyndns Update Result: ".$result)  
} else={  
  :log info ("UpdateDynDNS: No dyndns update needed")  
}  

Это скрипт для Mikrotik OS версии 5.x, но он есть и на вики Mikrotik.