Скрипт питания POE

Я обновил скрипт для версии 7.4, особенно часть с /system/health в конце, чтобы отслеживать целенаправленные изменения в способе работы отчёта о состоянии в ROS 7. Тестировал на CRS328-24P и hEX PoE, чтобы учесть случай с двойным питанием и с одним источником:

{
   :local ifWanted   "auto-on|forced-on|off"; # может быть одно или несколько, разделённых |, из auto-on, forced-on и off
   :local ifAlsoIdle  true; # может быть true или false. Если true — показывает PoE-интерфейсы даже в режиме ожидания
   :local ifMode      true; # может быть true или false. Если true — показывает, как установлен режим интерфейса
   :local pTotalCurr 0
   :local pTotalPowr 0
   :local div do={
       :local in  [:tostr $1]
       :local sym [:tostr $2]
       :local int [:pick $in 0 ([:len $in] - 1)]
       :local dec [:pick $in ([:len $in] - 1) [:len $in]]
       :local ret "$int.$dec$sym"
       :if ($ret = ".0$sym") do={:set ret "0.0$sym"}
       :return    $ret
   }
   :local form do={
       :local in   [:tostr $1]
       :local sym  [:tostr $2]
       :local temp "    $in"
       :return     "$[:pick $temp ([:len $temp] - 4) [:len $temp]]$sym"
   }
   :put ("Статус PoE:")
   /interface ethernet poe
   :foreach line in=[monitor [find where poe-out~$ifWanted] once as-value] do={
       :local ifName   ($line->"name")
       :local ifPOut   ($line->"poe-out")
       :local ifPVol   ($line->"poe-voltage")
       :local ifStatus ($line->"poe-out-status")
       :local pOutTens [$div ($line->"poe-out-voltage") "V"]
       :local pOutCurr [$form ($line->"poe-out-current") "mA"]
       :local pOutPowr [$div ($line->"poe-out-power") "W"]
       :set pTotalCurr ($pTotalCurr + ($line->"poe-out-current"))
       :set pTotalPowr ($pTotalPowr + ($line->"poe-out-power"))
       :local ifStrMod ""
       :if ($ifStatus = "powered-on") do={
           :if ($ifMode) do={:set ifStrMod " Режим: $ifPVol\t $ifPOut\t $ifStatus\t|"}
           :put ("Интерфейс: $ifName\t|$ifStrMod $pOutTens | $pOutCurr | $pOutPowr")
       } else={
           :if ($ifAlsoIdle) do={
               :set ifStrMod $ifStatus
               :if ($ifMode) do={:set ifStrMod "| Режим: $ifPVol\t $ifPOut\t $ifStatus"}
               :put ("Интерфейс: $ifName\t$ifStrMod")
           }
       }
   }
   :local sysPSU ""
   /system health
   :do {
       :local p1v [get [find name="psu1-voltage"] value]
       :set sysPSU "Блок питания низкий $p1v В"
       :do {
           :local p2v [get [find name="psu2-voltage"] value]
           :set sysPSU "$sysPSU | Блок питания высокий $p2v В"
       } on-error={}
   } on-error={
       :set sysPSU ([get [find name="voltage"] value] . "В")
   }
   :put ("Итого: $[$form $pTotalCurr "mA"] | $[$div $pTotalPowr "W"]")
   :put ("Routerboard: $sysPSU")
}

Обратите внимание на использование on-error вместо проверки typeof на nil. Как новичок в скриптах RouterOS, не уверен насчёт правильности, но такой способ кажется чище, чем проверка типа.

Привет, у меня вот такое сообщение. Это нормально? Я использую Mikrotik hex S > system/routerboard/export  
# 2024-01-16 22:49:56 by RouterOS 7.13.1  
# software id = 6H10-A1GS  
#  
# model = RB760iGS  

/system health print  
Columns: NAME, VALUE, TYPE  
#  NAME         VALUE  TYPE  
0  voltage      48.6   V  
1  temperature  69     C  

> sys script run poe-status  
POE Статус:  
Интерфейс:      | Режим:                  
Интерфейс:      | Режим:                  
Интерфейс:      | Режим:                  
Интерфейс:      | Режим:                  
Интерфейс:      | Режим:                  
Итого:    0мА | 0.0Вт  
Routerboard: 48.6В

Небольшой костыль, чтобы вывод был правильно отформатирован, когда длина имён интерфейсов отличается больше чем на один таб (8 символов). «11», добавляемое в расчёт, — это длина первого префикса, "Interface: " {

#poe-status  
:local poeOutStatus ""  
:local interfaceName ""  
:local poeOutPower 0  
:local poeOutPowerRemainder 0  
:local poeOutCurrent 0  
:local poeOutVoltage 0  
:local poeTotalPower 0  
:local poeResult [interface ethernet poe monitor [find] as-value once]
:local nameLen 0  
:local maxLen 0  
:local tabTo 0  
:local numTabs 0  
:local tab ""  

:foreach line in=$poeResult do={  
:set interfaceName ($line->"name")  
:if ([:len $interfaceName] > $maxLen) do={:set maxLen [:len $interfaceName]}
}  
:set tabTo ((((($maxLen+11)/8)+1)*8)-1)  

:put ("POE Status:")  
:foreach line in=$poeResult do={  
   :set poeOutStatus ($line->"poe-out-status")  
   :if ($poeOutStatus="powered-on") do={  
       :set interfaceName ($line->"name")  
       :set poeOutPower (($line->"poe-out-power")/10)  
       :set poeOutPowerRemainder (($line->"poe-out-power")-($poeOutPower*10))  
       :set poeOutCurrent ($line->"poe-out-current")  
       :set poeOutVoltage (($line->"poe-out-voltage")/10)  
       :set poeTotalPower ($poeTotalPower+($line->"poe-out-power"))  
:set nameLen ([:len $interfaceName] + 11)
       :set numTabs ((($tabTo-$nameLen)/8))  
:for i from=0 to=($numTabs) do={:set tab ($tab."\t")}  

       :put ("Interface: ".$interfaceName.$tab." | Power: ".$poeOutPower.".".$poeOutPowerRemainder."W\t | Current: ".$poeOutCurrent."mA\t | Voltage: ".$poeOutVoltage."V")  
       
:set tab ""  
       }  
   }  
:put ("Total Power: ".($poeTotalPower/10).".".(($poeTotalPower)-((($poeTotalPower/10))*10))."W")  
}

Так сложно понять, что это не работает на вашей модели? Что я написал не так или грубо в своем предыдущем ответе?