Запрос на добавление функции — DNS-имена в IPsec

Вот он:  
:local ddnsname "ddns.example.net";  
:local ipseccomment "уникальный комментарий";  
:global prevddns;  

:if ([ :typeof $prevddns ] = "nothing" ) do={
:global prevddns 0.0.0.0/0  
}  

:local currentddns [:resolve "$ddnsname"];

:if ($prevddns = $currentddns) do={  
#:log info ("No DDNS change...")  
} else={  

:log info ("IP-адрес DDNS изменился с " . "$prevddns" . " на " . "$currentddns")  

:local PolicyNumber [/ip ipsec policy find comment=$ipseccomment]
:local PeerNumber [/ip ipsec peer find comment=$ipseccomment]

/ip ipsec peer set $PeerNumber address="$currentddns/32"  
/ip ipsec policy set $PolicyNumber dst-address="$currentddns/32" sa-dst-address="$currentddns"  
/ip ipsec peer disable $PeerNumber  
/ip ipsec peer enable $PeerNumber  
/ip ipsec installed-sa flush  
/ip ipsec remote-peers kill-connections  

:log info ("Обновлено IPsec")  

:global prevddns $currentddns;  
}  

Ничего особенного, но работает для меня. Тебе нужно изменить ddnsname на свой (динамический) DNS-запись. И необходимо задать уникальный комментарий у IPsec Peer и Policy, которые хочешь динамически менять при смене IP по DNS. Оба — Peer и Policy — должны иметь одинаковый комментарий. Далее в строке скрипта ipseccomment указываешь этот же комментарий.  

В конце настрой скрипт на запуск через System > Scheduler с нужным интервалом в секундах или минутах.  

Я сам запускаю DDNS-сервис с TTL 1 секунда, поэтому новый IP распространяется почти моментально, и запускаю скрипт каждые 3 секунды. Если у твоего DDNS-сервиса TTL больше, запускать так часто не обязательно, но скрипт довольно лёгкий, можно даже каждую секунду запускать.  

В общем, скрипт просто резолвит имя DDNS и сравнивает с тем, что было при последнем запуске (или если запускается впервые — устанавливает 0.0.0.0/0 для инициализации переменной). Если IP изменился, он обновляет IPsec policy и peer, затем отключает и включает peer, а также сбрасывает соединения IPsec.  

Не знаю, правильно ли это или лучший метод, но у меня работает уже много лет без проблем.  

Используй и редактируй на здоровье!

нужно и мне тоже +1