Скрипт аренды DHCP для поддержки кэша DNS

Вот скрипт, который я написал для обновления статических записей DNS из DHCP-аренд. Его нужно вставить в скрипт аренды DHCP. По вопросу загрузки скрипта у меня ответа нет. Для работы необходима версия Router OS не ниже 6.39. Будьте осторожны при использовании на большом наборе DNS — он может удалять записи. Скрипт создан, чтобы поддерживать чистый локальный DNS без дублирующихся адресов и доменных имён.

Проблема с таким скриптом аренды DHCP в том, что он срабатывает только при установке связи с клиентом. Это значит, что если клиент просто обновляет аренду, а имя домена клиента изменилось, DNS не обновится. Даже если аренда обновится в конце периода, скрипт не выполнится. Было бы здорово, если бы скрипт аренды мог срабатывать и на другие события DHCP, а не только на bound (renew, release и т.д.), чтобы можно было обновлять и удалять записи DNS при изменениях или освобождении аренды DHCP.

Дайте знать, если найдёте решение этой проблемы.

# Записать статическую DNS-запись для каждой аренды DHCP

:local topdomain;
:local FullHostName;
:local NoUpdate false;

# Настройте ваш домен
:set topdomain "yourdomain.com";

:if ($leaseBound = 1) do={

 :set FullHostName ($"lease-hostname" . "." . $topdomain)

 /ip dns static;

 :foreach n in [find] do={
   # Если статическая запись DNS совпадает с арендой — не трогаем и помечаем, чтобы не обновлять
   :if (([get $n name] = $"FullHostName") and ([get $n address] = $leaseActIP)) do={
     :set NoUpdate true;
   } else={
     # Если существует запись с таким же FQDN или с таким же адресом — удаляем
     :if (([get $n name] = $"FullHostName") or ([get $n address] = $leaseActIP)) do={
       :log info ("Удаляем из статического DNS: " . [get $n name] . " @ " . [get $n address]);
       remove $n;
     }
   }
 }

 # Добавляем новую статическую запись DNS при необходимости
 :if ($NoUpdate = false) do={
   :log info ("Добавляем в статический DNS: " . $"FullHostName" .  " @ " . $leaseActIP);
   add name=($"lease-hostname" . "." . $topdomain) address=$leaseActIP;
 }

}

Да, думаю, ты просто можешь скопировать и вставить это в окно скрипта аренды DHCP сервера в Winbox. Я только что снова попробовал, и то, что я писал в предыдущем сообщении, не совсем точно. На самом деле скрипт срабатывает при освобождении DHCP. Вот новая версия скрипта с возможностью удаления DNS-записи, когда клиент освобождает DHCP.

# DNS запись для аренды DHCP

:local topdomain;
:local FullHostName;
:local NoUpdate false;

# Настройте свой домен
:set topdomain "yourdomain.com";

:set FullHostName ($"lease-hostname" . "." . $topdomain)

/ip dns static;

:if ($leaseBound = 1) do={

:foreach n in [find] do={
# Если статическая DNS-запись совпадает с арендой, оставляем её и ставим флаг, чтобы избежать обновления DNS
:if (([get $n name] = $"FullHostName") and ([get $n address] = $leaseActIP)) do={
:set NoUpdate true;
} else={
# Если уже есть DNS-запись с таким же полным доменным именем или адресом — удаляем её
:if (([get $n name] = $"FullHostName") or ([get $n address] = $leaseActIP)) do={
  :log info ("Удаляю из статического DNS: " . [get $n name] . " @ " . [get $n address]);
   remove $n;
 }
}
}
# Добавляем новую статическую DNS-запись, если нужно
:if ($NoUpdate = false) do={
:log info ("Добавляю в статический DNS: " . $"FullHostName" .  " @ " . $leaseActIP);
add name=($"lease-hostname" . "." . $topdomain) address=$leaseActIP;
}
# Удаляем DNS-запись при освобождении DHCP:
} else={
:log info ("Очищаю статическую DNS-запись при освобождении DHCP: " . $"FullHostName" . " @ " . $leaseActIP);
:foreach n in [find] do={
:if (([get $n name] = $"FullHostName") and ([get $n address] = $leaseActIP)) do={
remove $n;
 }
}
}

Ты также можешь использовать Webfig, чтобы скопировать и вставить скрипт. Если потом понадобится применить его на других роутерах, экспортируй конфигурацию DHCP через SSH или Telnet консоль командой: /ip dhcp-server export file=dhcp-config.rsc. Потом забери этот файл, например через FTP, отредактируй его в Notepad++ или похожем редакторе, чтобы убрать ненужные вещи, и скопируй на другие роутеры. После этого импортируй его снова через Telnet или SSH консоль командой: import file=dhcp-config.rsc. Так тебе не придется вручную экранировать lease-скрипт — экспорт/импорт сделает всё за тебя.

Похоже на похожий случай с обратным слэшем в Unicode CSS, экранированным (шестнадцатеричным) способом. То есть, на самом деле, основная кодировка — ASCII. Например, «é» превращается в \E9.